mirror of
https://gitee.com/mirrors_PX4/PX4-Autopilot.git
synced 2026-04-14 10:07:39 +08:00
1250563ed1
* rt106x: Use platform SPI hal layer * rt106x: Add romapi support and reboot to isp/bootloader * bootloader: imxrt_common: Add rt106x support * NXP MR-Tropic initial commit * Add missing file for mr-tropic bootloader * nxp-mr-tropic:Bootloader Alow Assertion debugging & Keep Ram Vectors * nxp-mr-tropic: Firmware Boot from bootloader * nxp-mr-tropic:Add Bootloader bin file * mr-tropic: Update config and linker Fixes enet issues with write-back and some code cleanup. Furthermore increase NOR LittleFS to 256kB to reflect on linker * Update NuttX * mr-tropic: fix itcm apping and add mr-tropic to itcm check --------- Co-authored-by: David Sidrane <David.Sidrane@NscDg.com>
178 lines
4.4 KiB
Plaintext
178 lines
4.4 KiB
Plaintext
/****************************************************************************
|
|
* boards/nxp/mr-tropic/nuttx-config/scripts/bootloader_script.ld
|
|
*
|
|
* Licensed to the Apache Software Foundation (ASF) under one or more
|
|
* contributor license agreements. See the NOTICE file distributed with
|
|
* this work for additional information regarding copyright ownership. The
|
|
* ASF licenses this file to you under the Apache License, Version 2.0 (the
|
|
* "License"); you may not use this file except in compliance with the
|
|
* License. You may obtain a copy of the License at
|
|
*
|
|
* http://www.apache.org/licenses/LICENSE-2.0
|
|
*
|
|
* Unless required by applicable law or agreed to in writing, software
|
|
* distributed under the License is distributed on an "AS IS" BASIS, WITHOUT
|
|
* WARRANTIES OR CONDITIONS OF ANY KIND, either express or implied. See the
|
|
* License for the specific language governing permissions and limitations
|
|
* under the License.
|
|
*
|
|
****************************************************************************/
|
|
|
|
/* Specify the memory areas */
|
|
|
|
MEMORY
|
|
{
|
|
flash (rx) : ORIGIN = 0x70000000, LENGTH = 128K
|
|
sram (rwx) : ORIGIN = 0x20200000, LENGTH = 512K
|
|
itcm (rwx) : ORIGIN = 0x00000000, LENGTH = 384K
|
|
dtcm (rwx) : ORIGIN = 0x20000000, LENGTH = 128K
|
|
}
|
|
|
|
OUTPUT_ARCH(arm)
|
|
EXTERN(_vectors)
|
|
EXTERN(g_flash_config)
|
|
EXTERN(g_image_vector_table)
|
|
EXTERN(g_boot_data)
|
|
EXTERN(board_get_manifest)
|
|
EXTERN(_bootdelay_signature)
|
|
|
|
ENTRY(_stext)
|
|
|
|
SECTIONS
|
|
{
|
|
/* Image Vector Table and Boot Data for booting from external flash */
|
|
|
|
.boot_hdr : ALIGN(4)
|
|
{
|
|
FILL(0xff)
|
|
__boot_hdr_start__ = ABSOLUTE(.) ;
|
|
KEEP(*(.boot_hdr.conf))
|
|
. = 0x1000 ;
|
|
KEEP(*(.boot_hdr.ivt))
|
|
. = 0x1020 ;
|
|
KEEP(*(.boot_hdr.boot_data))
|
|
. = 0x1030 ;
|
|
KEEP(*(.boot_hdr.dcd_data))
|
|
__boot_hdr_end__ = ABSOLUTE(.) ;
|
|
. = 0x2000 ;
|
|
} >flash
|
|
|
|
.vectors :
|
|
{
|
|
KEEP(*(.vectors))
|
|
*(.text .text.__start)
|
|
} >flash
|
|
|
|
.itcmfunc :
|
|
{
|
|
. = ALIGN(8);
|
|
_sitcmfuncs = ABSOLUTE(.);
|
|
FILL(0xFF)
|
|
. = 0x40 ;
|
|
*(.ram_vectors)
|
|
. = ALIGN(8);
|
|
_eitcmfuncs = ABSOLUTE(.);
|
|
} > itcm AT > flash
|
|
|
|
_fitcmfuncs = LOADADDR(.itcmfunc);
|
|
|
|
.text : ALIGN(4)
|
|
{
|
|
_stext = ABSOLUTE(.);
|
|
*(.vectors)
|
|
. = ALIGN(32);
|
|
/*
|
|
This signature provides the bootloader with a way to delay booting
|
|
*/
|
|
_bootdelay_signature = ABSOLUTE(.);
|
|
FILL(0xffecc2925d7d05c5)
|
|
. += 8;
|
|
*(.text .text.*)
|
|
*(.fixup)
|
|
*(.gnu.warning)
|
|
*(.gnu.linkonce.t.*)
|
|
*(.glue_7)
|
|
*(.glue_7t)
|
|
*(.got)
|
|
*(.gcc_except_table)
|
|
*(.gnu.linkonce.r.*)
|
|
. = ALIGN(4096);
|
|
_etext = ABSOLUTE(.);
|
|
_srodata = ABSOLUTE(.);
|
|
*(.rodata .rodata.*)
|
|
. = ALIGN(4096);
|
|
_erodata = ABSOLUTE(.);
|
|
} > flash
|
|
|
|
.init_section :
|
|
{
|
|
_sinit = ABSOLUTE(.);
|
|
KEEP(*(.init_array .init_array.*))
|
|
_einit = ABSOLUTE(.);
|
|
} > flash
|
|
|
|
.ARM.extab :
|
|
{
|
|
*(.ARM.extab*)
|
|
} > flash
|
|
|
|
.ARM.exidx :
|
|
{
|
|
__exidx_start = ABSOLUTE(.);
|
|
*(.ARM.exidx*)
|
|
__exidx_end = ABSOLUTE(.);
|
|
} > flash
|
|
|
|
_eronly = ABSOLUTE(.);
|
|
|
|
.data :
|
|
{
|
|
_sdata = ABSOLUTE(.);
|
|
*(.data .data.*)
|
|
*(.gnu.linkonce.d.*)
|
|
CONSTRUCTORS
|
|
. = ALIGN(4);
|
|
_edata = ABSOLUTE(.);
|
|
} > sram AT > flash
|
|
|
|
.ramfunc ALIGN(4):
|
|
{
|
|
_sramfuncs = ABSOLUTE(.);
|
|
*(.ramfunc .ramfunc.*)
|
|
_eramfuncs = ABSOLUTE(.);
|
|
} > sram AT > flash
|
|
|
|
_framfuncs = LOADADDR(.ramfunc);
|
|
|
|
.bss :
|
|
{
|
|
_sbss = ABSOLUTE(.);
|
|
*(.bss .bss.*)
|
|
*(.gnu.linkonce.b.*)
|
|
*(COMMON)
|
|
. = ALIGN(4);
|
|
_ebss = ABSOLUTE(.);
|
|
} > sram
|
|
|
|
/* Stabs debugging sections. */
|
|
|
|
.stab 0 : { *(.stab) }
|
|
.stabstr 0 : { *(.stabstr) }
|
|
.stab.excl 0 : { *(.stab.excl) }
|
|
.stab.exclstr 0 : { *(.stab.exclstr) }
|
|
.stab.index 0 : { *(.stab.index) }
|
|
.stab.indexstr 0 : { *(.stab.indexstr) }
|
|
.comment 0 : { *(.comment) }
|
|
.debug_abbrev 0 : { *(.debug_abbrev) }
|
|
.debug_info 0 : { *(.debug_info) }
|
|
.debug_line 0 : { *(.debug_line) }
|
|
.debug_pubnames 0 : { *(.debug_pubnames) }
|
|
.debug_aranges 0 : { *(.debug_aranges) }
|
|
|
|
_boot_loadaddr = ORIGIN(flash);
|
|
_boot_size = LENGTH(flash);
|
|
_ram_size = LENGTH(sram);
|
|
_sdtcm = ORIGIN(dtcm);
|
|
_edtcm = ORIGIN(dtcm) + LENGTH(dtcm);
|
|
}
|