Resync new repository with old repo r5166

git-svn-id: http://svn.code.sf.net/p/nuttx/code/trunk@5153 42af7a65-404d-4744-a932-0658087f49c3
2026-10-22 12:03:33 +08:00 · 2012-09-17 18:18:44 +00:00
commit 57623d42eb
5691 changed files with 1361853 additions and 0 deletions
@@ -0,0 +1,151 @@
+/****************************************************************************
+ * configs/ea3131/scripts/pg-ld.script
+ *
+ *   Copyright (C) 2010, 2012 Gregory Nutt. All rights reserved.
+ *   Author: Gregory Nutt <gnutt@nuttx.org>
+ *
+ * Redistribution and use in source and binary forms, with or without
+ * modification, are permitted provided that the following conditions
+ * are met:
+ *
+ * 1. Redistributions of source code must retain the above copyright
+ *    notice, this list of conditions and the following disclaimer.
+ * 2. Redistributions in binary form must reproduce the above copyright
+ *    notice, this list of conditions and the following disclaimer in
+ *    the documentation and/or other materials provided with the
+ *    distribution.
+ * 3. Neither the name NuttX nor the names of its contributors may be
+ *    used to endorse or promote products derived from this software
+ *    without specific prior written permission.
+ *
+ * THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
+ * "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
+ * LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS
+ * FOR A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE
+ * COPYRIGHT OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT,
+ * INCIDENTAL, SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING,
+ * BUT NOT LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS
+ * OF USE, DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED
+ * AND ON ANY THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT
+ * LIABILITY, OR TORT (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN
+ * ANY WAY OUT OF THE USE OF THIS SOFTWARE, EVEN IF ADVISED OF THE
+ * POSSIBILITY OF SUCH DAMAGE.
+ *
+ ****************************************************************************/
+ 
+/* The LPC3131 has 192Kb of ISRAM beginning at virtual address 0x1102:8000.
+ * LPC31xx boot ROM expects the boot image be compiled with entry point at
+ * 0x1102:9000.  A 128b header will appear at this address (applied by
+ * lpc313xImgCreator) and the executable code must begin at 0x1102:9080.
+ *
+ * The .text vitual address space begins at the same location as the physical
+ * address space:  0x1102 8000.  The virtual space is broken up into three
+ * regions:
+ *
+ *                                           PHYSICAL         VIRTUAL
+ *   NAME    DESCRIPTION                 SIZE    START    SIZE    START
+ *  -------- -------------------------- ----- ----------- ------- -----------
+ *   locked  Pages locked in memory.     48Kb 0x1102 8000  48Kb   0x1102 8000
+ *   paged   Pages in nonvolatile store. 96Kb 0x1103 4000 384Kb   0x1103 4000
+ *   data    .data/.bss/heap.            32Kb 0x1104 c000  32Kb   0x1109 4000
+ *           Reserved for page table     16Kb 0x1105 4000  16Kb   0x1109 c000
+ *  -------- -------------------------- ----- ----------- ------- -----------
+ *                                       192Kb 0x1105 8000 480Kb   0x110a 0000
+ *
+ * These region sizes must match the size in pages specified for each region
+ * in the NuttX configuration file:  CONFIG_PAGING_NLOCKED, CONFIG_PAGING_NVPAGED,
+ * and CONFIG_PAGING_NDATA.
+ *
+ * NOTE 1: The locked region is really big here so that you can enable lots of
+ * debug output without overflowing the locked region.  32Kb would probably be
+ * plenty if this were a real, optimized application.
+ *
+ * NOTE 2: Different compilers will compile the code to different sizes.  If you
+ * get a link time error saying that the locked region is full, you may have to
+ * re-organize this memory layout (here and in defconfig) to make the locked
+ * region even bigger.
+ */
+
+MEMORY
+{
+    locked (rx) : ORIGIN = 0x11029080, LENGTH = 48K - 4224
+    paged  (rx) : ORIGIN = 0x11034000, LENGTH = 384K
+    data   (rw) : ORIGIN = 0x11094000, LENGTH = 44K
+}
+
+OUTPUT_ARCH(arm)
+ENTRY(_stext)
+SECTIONS
+{
+	.locked : {
+		_slocked = ABSOLUTE(.);
+		*(.vectors)
+		up_head.o locked.r (.text .text.*)        
+		up_head.o locked.r (.fixup)
+		up_head.o locked.r (.gnu.warning)
+		up_head.o locked.r (.rodata .rodata.*)        
+		up_head.o locked.r (.gnu.linkonce.t.*)
+		up_head.o locked.r (.glue_7)
+		up_head.o locked.r (.glue_7t)
+		up_head.o locked.r (.got)
+		up_head.o locked.r (.gcc_except_table)
+		up_head.o locked.r (.gnu.linkonce.r.*)
+		_elocked = ABSOLUTE(.);
+	} >locked
+
+	_eronly = ABSOLUTE(.);
+
+	.paged : {
+		_spaged = ABSOLUTE(.);
+		*(.text .text.*)        
+		*(.fixup)
+		*(.gnu.warning)
+		*(.rodata .rodata.*)        
+		*(.gnu.linkonce.t.*)
+		*(.glue_7)
+		*(.glue_7t)
+		*(.got)
+		*(.gcc_except_table)
+		*(.gnu.linkonce.r.*)
+		_epaged = ABSOLUTE(.);
+	} > paged
+
+	.data : {
+		_sdata = ABSOLUTE(.);
+		*(.data .data.*)
+		*(.gnu.linkonce.d.*)
+		CONSTRUCTORS
+		_edata = ABSOLUTE(.);
+	} > data AT > locked
+
+	.ARM.extab : {
+		*(.ARM.extab*)
+	} >data
+
+	.ARM.exidx : {
+		__exidx_start = ABSOLUTE(.);
+		*(.ARM.exidx*)
+		__exidx_end = ABSOLUTE(.);
+	} > data
+
+	.bss : {
+		_sbss = ABSOLUTE(.);
+		*(.bss .bss.*)
+		*(.gnu.linkonce.b.*)
+		*(COMMON)
+		_ebss = ABSOLUTE(.);
+	} > data
+					/* Stabs debugging sections.	*/
+	.stab 0 : { *(.stab) }
+	.stabstr 0 : { *(.stabstr) }
+	.stab.excl 0 : { *(.stab.excl) }
+	.stab.exclstr 0 : { *(.stab.exclstr) }
+	.stab.index 0 : { *(.stab.index) }
+	.stab.indexstr 0 : { *(.stab.indexstr) }
+	.comment 0 : { *(.comment) }
+	.debug_abbrev 0 : { *(.debug_abbrev) }
+	.debug_info 0 : { *(.debug_info) }
+	.debug_line 0 : { *(.debug_line) }
+	.debug_pubnames 0 : { *(.debug_pubnames) }
+	.debug_aranges 0 : { *(.debug_aranges) }
+}